***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 29, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJX8806     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     72.01
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=2.8  VTO=1.08  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=2.5e10  gamma=0.55)
Rd     d1    d2    200m TC=4m,3u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=22  TBV1=6.855e-4   CJO=5.570e-12  M=3.256e-1  VJ=3.909e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.306e-9  N=1.252  RS=0.04u  EG=0.8  TT=20n ikf=9.233e-1)
Rdiode  d1  21    7.892e-1 TC=-2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   3.415e-11
.MODEL     DGD    D(M=5.356e-1   CJO=3.415e-11   VJ=5.953e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    4.25617e-11
.ENDS
*$
